ASP source example


	CoverYourASP --> "/CategoryPage.html" --> Source

	Free membership
	Join in the fun! Sign in Member Services

	Site navigation
	Download the entire site! Search my articles Free Magazines Browse the directory Send me feedback Buy my boxer shorts Recommend this page Printer-friendly page Resources I recommend Link to my site Advertising slashed! About your privacy Legal stuff

	Site statistics
	10 active users 1194 visitors today 939 pages today (only part of today)

	Tools I use

CoverYourASP

• ASP.NET Blog
• RSS submissions
• E-commerce

This page shows the actual source code used on this site. You can read the article that discusses this code here.

If this is the first CYA source code you've seen you should read this overview first.

Did you know you can download all the source code (and the database) of this site? Then get my newsletter to be emailed when I update the source code!

Please spread the word by recommending my site to your friends and colleagues!

This is JScript (server-side JavaScript), not the more common VBScript. More...

CategoryPage.asp


<%
// ============================================
// NOTE: all source code downloaded from CoverYourASP was written by
// James Shaw (unless stated otherwise), and is copyright (c) 2000-2002
// by James Shaw. You can use the code for any purpose, but do not
// publish or distribute the content in any way.
//
// See http://CoverYourASP.com/Legal.asp for up-to-date details.
// ============================================

// get the categories from the URL
var nCategories = Request.QueryString( "cat" ).Count;

// move them into an array for later processing
var sCategories = new Array;

if ( 0 == nCategories )
{
   // stop weirdo's playing with URL
   nCategories = 1;
   sCategories [ 0 ] = "Entertainment";
}
else
{
   var i;
   for ( i = 0; i < nCategories; i++ )
      sCategories [ i ] = Request.QueryString( "cat" )( i+1 );
}

// Initialize database
DBInitConnection ( );

// make sure there is at least one sub-category to display
// or I can proceed straight to the results page
DBGetRecords ( 'SELECT CategoryID FROM Categories WHERE ParentCategoryID=\'' + sCategories [ nCategories-1 ] + '\';' );

if ( oRecordSet.EOF )
{
   DBReleaseConnection ( );
   // use Server.Transfer when on IIS5
   Redirect ( '/ResultsPage_cat_.html' + Server.URLEncode( sCategories [ 0 ] ) + '&cat=' + Server.URLEncode( sCategories [ nCategories-1 ] ) );
}

// free up the connection
DBReleaseConnection ( );

// increment the parent articles counter
sIncArticlePage = '/Categories.html';

// output relevant meta tags
Init( sCategories [ 0 ] + " Categories", "Categories, yahoo, category, portal" );

// output common top of page
Header( '<a href="/categories.html">Categories</a> --> ' + sCategories [0] );

// output page content
Content ( );

// output common bottom of page
Footer( );

// ============================================
// the content of this page
// ============================================
function Content ( )
{
   Out ( '<td colspan=2    valign="top" class="content">' );

      Out ( 'This is where I can start browsing the sub-categories. I came up with this design after reviewing a lot of sites - I chose this way because you can quickly choose a different category without having to "back up" to the level you want to change. Try clicking on all the categories in the left column and you\'ll see what I mean.' );

      Out ( '<p>When you click on a category without any sub-categories you\'ll get sent to the results page...' );

      // the table wrapping the categories tables
      Out ( '<p><table cellspacing=0 cellpadding=10><tr>' );

      // Initialize database
      DBInitConnection ( );

      for ( var nLevel = 0; nLevel < nCategories; nLevel++ )
      {
         // get list of categories at this level
         DBGetRecords ( 'SELECT CategoryID FROM Categories WHERE ParentCategoryID=\'' + sCategories [nLevel] + '\';' );

         if ( oRecordSet.EOF )
            // shouldn't happen...
            return;

         Out ( '<td valign="top" ><table cellspacing=0 cellpadding=2>' );

         var sCat;      // internal category name in database

         var sLink = MakeQueryString ( nLevel+1 );
         var sLevelChar;
         var sLine;

         if ( nLevel == nCategories-1 )
            sLevelChar = "&gt";
         else
            sLevelChar = " ";

         while ( !oRecordSet.EOF )
         {
            sCat = "" + oRecordSet( 0 );

            var sContChar = sLevelChar;

            sLine = '<tr>';

            if ( sCat == sCategories [nLevel+1] )
            {
               sLine += '<td bgcolor="#FF3300"><b><a style="color:#FFFFFF"';
               sContChar = "&gt";
            }
            else
            {
               sLine += '<td><b><a';
            }

            Out ( sLine + ' href="CategoryPage.asp?' + sLink + '&cat=' + Server.URLEncode( sCat ) + '">' + sCat + '</a></b></td><td>' + sContChar + '</td></tr>' );

            oRecordSet.MoveNext();
         }

         Out ( '</table></td>' );
      }

      // free up the connection
      DBReleaseConnection ( );

      Out ( '</tr></table>' );

      Out ( '<p><center><a href="/ShowSource_page_CategoryPage.html"><img src="/images/source.gif" border=0></a></center>' );

   Out ( '</td>' );
}

// ============================================
// takes the query string and strips it off to the specified level.
// e.g. given QueryString == "cat=1&cat=2&cat=3&cat=4" and
// nLevel == 2, I return "cat=1&cat=2"
// ============================================
function MakeQueryString ( nLevel )
{
   var sQueryString = '';

   for ( i = 0; i < nCategories && i < nLevel; i++ )
   {
      if ( i > 0 )
         sQueryString += '&';

      sQueryString += 'cat=' + Server.URLEncode( sCategories [ i ] );
   }

   return sQueryString;
}
%>

utils/ShowCategory.asp
<%
// ============================================
// NOTE: all source code downloaded from CoverYourASP was written by
// James Shaw (unless stated otherwise), and is copyright (c) 2000-2002
// by James Shaw. You can use the code for any purpose, but do not
// publish or distribute the content in any way.
//
// See http://CoverYourASP.com/Legal.asp for up-to-date details.
// ============================================

// ============================================
// show the top category and as many sub-categories as will fit in <50
// characters
// ============================================
function ShowCategory ( sOffset, sTop )
{
   var sTopURL = '<a href="CategoryPage.asp?cat=';

   // if I'm given an sOffset then I'll prefix all URLs with it
   // this helps me when I'm demonstrating using a database
   // with only 3 levels (at most) of sub-category - see Columns.asp
   if ( sOffset.length )
      sTopURL += Server.URLEncode( sOffset ) + '&cat=';

   sTopURL += Server.URLEncode( sTop );

   Out ( '<p><font size=3><b>' + sTopURL + '" title="Browse ' + sTop + ' categories">' + sTop + '</a></b></font><br>' );

   DBGetRecords ( 'SELECT CategoryID FROM Categories WHERE ParentCategoryID=\'' + sTop + '\'' );

   var sSubs = "";
   var sSep = "";
   var nLen = 0;

   // show sub-categories until more than 50 characters
   while ( !oRecordSet.EOF )
   {
      var sSub = "" + oRecordSet ( 0 );

      nLen += sSep.length + sSub.length;

      if ( nLen > 50 )
         break;

      sSubs += sSep + sTopURL + '&cat=' + Server.URLEncode( sSub ) + '">' + sSub + '</a>';

      sSep = ", ";

      oRecordSet.MoveNext ( );
   }

   DBReleaseRecords ( );

   Out ( sSubs + '..' );
}
%>

utils/Database.asp
<%
// ============================================
// NOTE: all source code downloaded from CoverYourASP was written by
// James Shaw (unless stated otherwise), and is copyright (c) 2000-2002
// by James Shaw. You can use the code for any purpose, but do not
// publish or distribute the content in any way.
//
// See http://CoverYourASP.com/Legal.asp for up-to-date details.
// ============================================

// globals
var oConnection;
var oRecordSet;

// enums

// Connection.State and Recordset.State property
var adStateClosed = 0;         // the object is closed.
var adStateOpen = 1;             // the object is open.
var adStateConnecting = 2;   // the object is connecting.
var adStateExecuting = 4;      // the object is executing a command.
var adStateFetching = 8;         // the rows of the object are being fetched.

// Recordset.Cursor property
var adOpenUnspecified = -1;   // does not specify the type of cursor.
var adOpenForwardOnly = 0;   // (default) a forward-only cursor, i.e. you get only one pass thru the data!
var adOpenKeyset = 1;         // can go in any direction, and as a bonus you'll see changes other users make.  EXPENSIVE!
var adOpenDynamic = 2;      // as Keyset, but also you can see additions/deletions other users make.  EXPENSIVE!
var adOpenStatic = 3;         // can go in any direction, but read-only.

// Recordset.LockType property
var adLockUnspecified = -1;   // does not specify a type of lock.
var adLockReadOnly = 1;      // (default) guess!
var adLockPessimistic = 2;      // guaranteed to work
var adLockOptimistic = 3;      // records locked only when you call Update. fingers crossed
var adLockBatchOptimistic = 4;// required for batch update mode

var adCmdUnspecified = -1;   // Does not specify the command type argument.
var adCmdUnknown = 8;      // Default. Indicates that the type of command in the CommandText property is not known.
var adCmdText = 1;            // a textual definition of a command or stored procedure call.
var adCmdTable = 2;            // a table name whose columns are all returned by an internally generated SQL query.
var adCmdStoredProc = 4;      // a stored procedure name.
var adCmdFile = 256;            // a persisted Recordset.
var adCmdTableDirect = 512;   // a table name whose columns are all returned.

// SchemaEnum - specifies the type of schema Recordset to be retrieved by the OpenSchema method
var adSchemaTables = 20;      // returns the tables
var adSchemaForeignKeys = 27   // returns the foreign keys (relationships)
// ============================================
// example usage:
//      DBInitConnection ( );
//
//      DBGetRecords ( "SELECT * FROM Somewhere" );
//
//      ...use oRecordSet
//
//      DBReleaseRecords ( );      // optional step
//
//      DBGetRecords ( "SELECT * FROM SomewhereElse" );
//
//      ...use oRecordSet
//
//      DBReleaseRecords ( );      // optional step
//
//      DBReleaseConnection ( );
// ============================================

// ============================================
// initializes database variables for first use on page - leave it to the
// last possible second before calling this function
// ============================================
function DBInitConnection ( )
{
   // don't open it again if already opened!
   if ( oConnection != undefined )
      return;

   // don't bother trying to open if path is below SSI folders
   if ( -1 != sDBPath.indexOf ( '\\utils\\' ) || -1 != sDBPath.indexOf ( '\\include\\' ) )
      return;

   // you can open Recordset objects without a Connection object, but
   // it's far less efficient if you are opening multiple Recordsets.
   //
   // if you don't create a Connection object ADO creates a new one for
   // each new Recordset.Open, even if you use the same connection string.
   oConnection = Server.CreateObject( 'ADODB.Connection' );

   try
   {
      // open the database, catching any errors that occur
      oConnection.Open( sConnectionString );
   }
   catch ( e )
   {
      // display error message, and send email
      DatabaseException ( e );

      // quit running the script completely
      Response.End ( );
   }

   // create a Recordset
   oRecordSet = Server.CreateObject( 'ADODB.Recordset' );
}

// ============================================
// tidies up after DBInitConnection
// ============================================
function DBReleaseConnection ( )
{
   // don't release the connection if not connected!
   if ( oConnection == undefined )
      return;

   // close and delete the Recordset object
   DBReleaseRecords ( );

   oRecordSet = undefined;

   // Don't call Close if the Recordset failed to Open properly, i.e. its
   // State is still adStateClosed (0)
   if ( oConnection.State != adStateClosed )
      oConnection.Close();

   oConnection = undefined;
}

// ============================================
// executes the passed in SQL statement and returns a read-only
// forward-only oRecordSet object
// ============================================
function DBGetRecords ( sSQL )
{
   // if the Recordset is already open, close it
   DBReleaseRecords ( );

   // I could use oRecordSet = oConnection.Execute( sSQL ) here
   // but then I will always get back a read-only, forward-only cursor.
   // (admittedly this is the most used type, but still)

   // use oRecordSet.Open and I have far more control. For details
   // read the definitions of the enums at the top of this file.

   //Out ( sSQL );Response.Flush();

   try
   {
      // remember that this can fail if passed garbage, and hence the
      // Recordset will remain closed, State == adStateClosed
      if ( oConnection )
         oRecordSet.Open ( sSQL, oConnection, adOpenForwardOnly, adLockReadOnly );
   }
   catch ( e )
   {
      // display error message, and send email
      DatabaseException ( e );

      // quit running the script completely
      Response.End ( );
   }
}

// ============================================
// tidies up after DBGetRecords
// ============================================
function DBReleaseRecords ( )
{
   // when you have finished with an open Recordset object, call the
   // Close method to release its resources. You can call Open again.

   // Don't call Close if the Recordset failed to Open properly, i.e. its
   // State is still adStateClosed
   if ( oRecordSet != undefined && oRecordSet.State != adStateClosed )
      oRecordSet.Close();
}

// ============================================
// display exception message, but strip out database path if necessary
// ============================================
function DatabaseException ( e )
{
   Out ( '<table bgcolor="#ff0000" cellpadding="20"><tr><td>' );

      Out ( '<h4><font color="white">An error has occured while connecting to the database:</font></h4>' );

      var sMessage = e.description;

      // strip out the database path if present
      var nStart = sMessage.indexOf ( sDBPath )

      if ( -1 != nStart )
         sMessage = sMessage.slice ( 0, nStart ) + '[database path]' + sMessage.slice ( nStart + sDBPath.length );

      Out ( '<h4>   "' + sMessage + '"</h4>' );

      Out ( '<h4><font color="white">Don\'t despair - this problem is probably well-documented in my <a href="http://CoverYourASP.com/Trouble.asp"><font color="white">trouble-shooting</font></a> section.</font></h4>' );

   Out ( '</td></tr></table>' );

   // make up the message body
   var sBody = 'The file "' + Request.ServerVariables ( "URL" ) + '?' + Request.QueryString ( ) + '" generated a database error\n\n';

   sBody += 'Referrer: "' + Request.ServerVariables ( "HTTP_REFERER" ) + '".\n';
   sBody += 'Browser: "' + Request.ServerVariables ( "HTTP_USER_AGENT" ) + '".\n';
   sBody += 'IP address: "' + Request.ServerVariables ( "REMOTE_ADDR" ) + '".\n';

   var dateToday = new Date();

   sBody += 'Time: "' + dateToday.getHours() + ':' + dateToday.getMinutes() + '".\n';

   sBody += sMessage;

   // send the email
   SendEmail ( 'Database.Exception', 'BadDB@' + sHostDomain, '', 'Reporting exception', sBody );
}

// ============================================
// are we using Jet engine db, or SQL server?
// ============================================
var bUsingJet;

function DBIsJet ( )
{
   // for efficiency, only work out if which I'm using
   // the first time I'm used on a page.
   if ( bUsingJet == undefined )
      bUsingJet = ( -1 != sDBDriver.indexOf ( '.Jet.' ) );

   return bUsingJet;
}

// ============================================
// wrap date in relevant delimeters depending on db engine
// ============================================
function DBWrapDate ( sDate )
{
   return ( DBIsJet ( ) ? '#' + sDate + '#' : '\'' + sDate + '\'' );
}

// ============================================
//
// ============================================
function DBIsNull ( )
{
   return ( DBIsJet ( ) ? 'Is Null' : '= null' );
}

// ============================================
// stores dropdown lists in Application variables for use with foreign keys
// ============================================
function DBGatherForeignKeys ( )
{
   if ( !Application ( 'GatheredForeignKeys' ) )
   {
      DBInitConnection ( );

      bDebug = true;

      oRecordSet = oConnection.OpenSchema ( adSchemaForeignKeys );

      var nFields = oRecordSet.Fields.Count;
      var bHeaders = false;

      var sRefTables = new Array;
      var sRefColumns = new Array;
      var sForeignTables = new Array;
      var sForeignColumns = new Array;
      var nForeign = 0;

      while ( !oRecordSet.EOF )
      {
         if ( IsDebug ( ) )
         {
            if ( !bHeaders )
            {
               Out ( '<table border="1"><tr>' );

               for ( i=0; i<nFields; i++ )
                  Out ( '<td>' + oRecordSet.Fields ( i ).Name + '</td>' );

               Out ( '</tr>' );

               bHeaders= true;
            }

            Out ( '<tr>' );

            for ( i=0; i<nFields; i++ )
               Out ( '<td>' + oRecordSet ( i ) + '</td>' );

            Out ( '</tr>' );
         }

         sRefTables [ nForeign ] = '' + oRecordSet ( 'FK_TABLE_NAME' );
         sRefColumns [ nForeign ] = '' + oRecordSet ( 'FK_COLUMN_NAME' );
         sForeignTables [ nForeign ] = '' + oRecordSet ( 'PK_TABLE_NAME' );
         sForeignColumns [ nForeign++ ] = '' + oRecordSet ( 'PK_COLUMN_NAME' );

         oRecordSet.MoveNext  ( );
      }

      if ( bHeaders )
         DebugOut ( '</table>' );

      for ( i=0; i<nForeign; i++ )
      {
         DBGetRecords ( 'SELECT * FROM ' + sForeignTables [ i ] );

         try
         {
            var sList = '<select name="' + sRefColumns [ i ] + '">';
            var sForeignColumn = sForeignColumns [ i ];

            while ( !oRecordSet.EOF )
            {
               // I assume that the second field is
               // the one to show in dropdown list
               sList += '<option value="' + oRecordSet ( sForeignColumn ) + '">' + oRecordSet ( 1 ) + '</option>';

               oRecordSet.MoveNext  ( );
            }

            sList += '</select>';

            Application ( sRefTables [ i ] + ':' + sRefColumns [ i ] ) = sList;

            DebugOut ( '<p>Created ' + sRefTables [ i ] + ':' + sRefColumns [ i ] );
            DebugOut ( '<p>' + sRefColumns [ i ] + '=' + sForeignTables [ i ] + ':' + sForeignColumn + ' output:'+ Server.HTMLEncode ( sList ) + sList );
         }
         catch ( e )
         {
            DebugOut ( '<p>Failed to create dropdown list for ' + sRefTables [ i ] + ':' + sRefColumns [ i ] );
         }
      }

      DBReleaseConnection ( );

      Application ( 'GatheredForeignKeys' ) = true;
   }
}

// ============================================
// display (not editable) recordset column value
// ============================================
function DBDisplayValue ( oRecordSet, sTableName, nColumn )
{
   var sColumnName = oRecordSet.Fields ( nColumn ).Name;
   var oValue = oRecordSet ( nColumn );

   // get dropdown list if a foreign key
   var sHTML = Application ( sTableName + ':' + sColumnName );

//   DebugOut ( '<p>Application (  ' + sTableName + ':' + sColumnName + '=' + sHTML );

   if ( sHTML )
   {
      // disable control
      var nIndex = sHTML.indexOf ( ' name' );

      if ( nIndex != -1 )
         sHTML = sHTML.slice ( 0, nIndex ) + ' disabled' + sHTML.slice ( nIndex );

      // place 'selected' in the correct spot
      var nIndex = sHTML.indexOf ( ' value="' + oValue );

      if ( nIndex != -1 )
         sHTML = sHTML.slice ( 0, nIndex ) + ' selected' + sHTML.slice ( nIndex );
   }
   else
   {
      // show prettier dates
      if ( oValue.Type == 7/*date*/ )
         sHTML = FormatDateDMY ( oValue );
      else
         sHTML = "" + Server.HTMLEncode ( '' + oValue );

      // for brevity show the first x characters only
      if ( sHTML.length > 35 )
         sHTML = sHTML.slice ( 0, 35 ) + '...';
   }

   return sHTML;
}

// ============================================
// display editable recordset column value
// ============================================
function DBEditValue ( oRecordSet, sTableName, nColumn )
{
   var sColumnName = oRecordSet.Fields ( nColumn ).Name;
   var oValue = oRecordSet ( nColumn );

   // get dropdown list if a foreign key
   var sHTML = Application ( sTableName + ':' + sColumnName );

//   DebugOut ( '<p>Application (  ' + sTableName + ':' + sColumnName + '=' + sHTML );

   if ( sHTML )
   {
      // place 'selected' in the correct spot
      var nIndex = sHTML.indexOf ( ' value="' + oValue );

      if ( nIndex != -1 )
         sHTML = sHTML.slice ( 0, nIndex ) + ' selected' + sHTML.slice ( nIndex );
   }
   else
   {
      // show prettier dates
      if ( oValue.Type == 7/*date*/ )
         sHTML = FormatDateDMY ( oValue );
      else
         sHTML = "" + Server.HTMLEncode ( '' + oValue );

      sHTML = '<input type="text" name="' + sColumnName + '" size="45" value="' + sHTML + '">';
   }

   return sHTML;
}

// ============================================
// return value with ' replaced by SQL-safe ''
// ============================================
function DBEncode ( sValue )
{
   return sValue.replace ( /\'/g, '\'\'' );
}
%>

The Categories table

The layout of the table is simple. There are three fields: CategoryID, ParentCategoryID and TopCategoryID. The entire database is contained in the download.

Hopefully much of this is self-explanatory. If not, or if you see ways that I can improve the code, please drop me a line.

To see the source code for this page, click on the icon below.

	Featured sponsor

	My favorite resources
	I share my content Do you need a quick and easy way to link to my articles? All the information you need is published with ASPRSS... Free subscriptions to industry leading publications for those who qualify! See my source code wherever you see this icon... You can also download the entire site source code for FREE! Brand yourself as a top professional: create quotes and amazing proposals and get many legal documents free! The latter saved me 3 times the purchase price on the first day I owned it! I don't make a penny from these, but they're a lot of fun! Don't you need a new mouse mat?